[VarDef,numberOfLayers,0]

//****routine to toggle Record for current layer*****************
[RoutineDef,ToggleRecord,
    [VarSet,layerPath,[StrMerge,"Tool:Layers:",[IGetTitle,"Tool:Layers:Layer Intensity"]]]       
    //turn on Layer recording if necessary
    [VarSet,wid,[IWidth,layerPath]]   
    [If,([IModGet,layerPath]&1) != 1,
        //set Intensity to 1 for recording
        [ISet,Tool:Layers:Layer Intensity,1]               
        [IClick,layerPath,wid-28,5]//turn on recording       
        [VarSet,recOn,1]
    ,//else turn off record       
        [ISet,"Tool:Layers:Layer Intensity",0]           
        [VarSet,recOn,0]
    ]
]//end routine



//****routine to find the number of layers*****************
[RoutineDef,GetLayers,
	[VarSet,numberOfLayers,0]
	[If,[IsEnabled,Tool:Layers:Layers Scrollbar],		
		//store current scroll bar position
		[VarSet,tmpLyScrPos,[IGetSecondary,Tool:Layers:Layers Scrollbar]]
		//set scroll bar to a maximum to ensure it is at the top
		[ISet,Tool:Layers:Layers Scrollbar,0,256]
		[VarSet,numberOfLayers,[IGetSecondary,Tool:Layers:Layers Scrollbar]+1]
	,
		[If,[IsEnabled,"Tool:Layers:Layer Intensity"],
			[VarSet,numberOfLayers,1]	
		]
	]
]//end routine



[IButton,ToggleRecord,,
	
	[IFreeze,	
		[VarSet,tmpSDiv,[IGet,Tool:Geometry:SDiv]]
		[ISet,Tool:Geometry:SDiv,[IGetMax,Tool:Geometry:SDiv]]	
		[RoutineCall,GetLayers]	
		[If,numberOfLayers > 0,
			[Loop,numberOfLayers,
				[ISet, Tool:Layers:Layers ScrollBar, 0, [Val,n]]
				[VarSet,layerPath,[StrMerge,"Tool:Layers:",[IGetTitle,"Tool:Layers:Layer Intensity"]]]
				[If,[IGetFlags,layerPath]>=10,
					[LoopExit]
				]		
			,n]			
			[RoutineCall,ToggleRecord]
		]
	]//end freeze
]