[RoutineDef,DoAllSubTools,
	[VarSet,activST,[SubToolGetActiveIndex]]
	[Loop,[SubToolGetCount],//loop through all subtools
		[SubToolSelect,[Val,n]]
		[If,(mode == 0),
			[If,[IExists,Tool:Texture Map:Texture On]&&[IsEnabled,Tool:Texture Map:Texture On],
				[IUnPress,Tool:Texture Map:Texture On]
			]
		]
		[If,(mode == 1),
			[If,[IExists,Tool:Texture Map:Texture On]&&[IsEnabled,Tool:Texture Map:Texture On],
				[IKeyPress,'2',[IPress,Tool:Texture Map:Texture On]]
			]
		]
		[If,(mode == 2),
			[If,[IExists,Tool:Visibility:ShowPt]&&[IsEnabled,Tool:Visibility:ShowPt],
				[IPress,Tool:Visibility:ShowPt]
			]
		]
		[If,(mode == 3),
			[If,[IExists,Tool:Masking:Clear]&&[IsEnabled,Tool:Masking:Clear],
				[IPress,Tool:Masking:Clear]
			]
		]
		[If,(mode == 4),
			[If,[IExists,Tool:UV Map:Delete UV]&&[IsEnabled,Tool:UV Map:Delete UV],
				[IPress,Tool:UV Map:Delete UV]
			]
		]
		[If,(mode == 5),
			[If,[IExists,Tool:Morph Target:DelMT]&&[IsEnabled,Tool:Morph Target:DelMT],
				[IPress,Tool:Morph Target:DelMT]
			]
		]				
	,n]	
	[SubToolSelect,activST]		
,mode]



[IButton,"Texture Off","Texture Off for All SubTools",
	[RoutineCall,DoAllSubTools,0]
]

[IButton,"Texture On","Texture On for All SubTools",
	[RoutineCall,DoAllSubTools,1]
]

[IButton,"Show Hidden","Show Hidden for All SubTools",
	[RoutineCall,DoAllSubTools,2]
]

[IButton,"Clear Mask","Clear Mask for All SubTools",
	[RoutineCall,DoAllSubTools,3]
]

[IButton,"Delete UVs","Delete UVs for All SubTools",
	[RoutineCall,DoAllSubTools,4]
]

[IButton,"Delete Morph Target","Delete Morph Target for All SubTools",
	[RoutineCall,DoAllSubTools,5]
]