// ObjOutIn.txt  - Svengali July 08 - revised marcus_civis December 2018
// load and save Object File = 1.obj
// Groups disabled on save
// revised for Maya MA by marcus_civis October 2 2021

[IConfig, 2021]
[IShowActions, 0]

[VarDef, Object1, "" ]

[RoutineDef,SetPath,
	[If,[FileExists,[FileNameResolvePath,"ZPUBLIC_Temp/MApath.zvr"]],
		[VarLoad,Object1,[FileNameResolvePath,"ZPUBLIC_Temp/MApath.zvr"]]
		,//else
		[If,md,
			[VarSet, Object1,[FileNameAsk,"Maya(*.ma)|*.MA||","Model.ma","Please Save File..."]]
			,
			[VarSet, Object1,[FileNameAsk,"Maya(*.ma)|*.MA||",,"Please Open File..."]]
		]
		[If,[StrLength,Object1],
			[VarSave,Object1,[FileNameResolvePath,"ZPUBLIC_Temp/MApath.zvr"]]
			,//else exit if no file name
			[Exit]			
		]
	]
,md]

[IButton,"TOOL:Maya out","Export model as Maya MA",
	[RoutineCall,SetPath,1]
	[If, [IGet, TRANSFORM:Edit] == 1,
		[ISet, Preferences:ImportExport:Grp, 0 ]		
		[If,[IsEnabled,TOOL:Export],			
			[MemDelete, Mem_Export]
			[MemCreateFromFile, Mem_Export, "ZSTARTUP_ExportTamplates/Maya.ma"]
		 	[FileNameSetNext, Object1, MemBlock:Mem_Export]
			[IPress, Tool:Export]
			[MemDelete, Mem_Export]			
			[Note, "Model Saved as Maya MA...", , 2 ]
		]
	, // else
		[Note, "No model in edit mode...", , 2 ]
	]
,,0.34]

[IButton,"TOOL:Maya in","Import model Maya MA",
	[RoutineCall,SetPath,0]
	[If, [FileExists, Object1 ] == 1,
		[FileNameSetNext, Object1 ]
		[IKeyPress, 13, [IPress, TOOL:Import] ]
		[Note, "model Maya MA has been loaded...", , 2 ]
	, // else
		[Note, "Sorry, Maya MA does not exist...", , 2 ]
	]

,,0.33]

[IButton,"TOOL:Reset","Reset Maya MA path",
	[If,[FileExists,"ZPUBLIC_Temp/MApath.zvr"],
		[FileDelete,"ZPUBLIC_Temp/MApath.zvr"]
	]
	[Note,"Maya MA path reset",,2]	
,,0.33]